scripting overhaul testing

[sjek]

Another round. Awesome coomunity btw.

MWSE is developed kinda heavily http://forums.bethsoft.com/topic/152794 ... er-mwse-2/
Also newer MWSE 2.0 rewrite https://mwse.readthedocs.io/en/latest/l ... ction.html

This is gonna be incremental

This esp makes interior cell named aatest. will need overhaul later on.
https://www.dropbox.com/s/a5skbr2o7goab ... t.esp?dl=0
To bypass vanilla file corruption, done in openmw-cs.

Basically needs some structure and need to make rooms for different function groups.
Something activated or distance / global trickered, giving message confirmation if all works.
ideas welcome for something suitable.

1. http://www.uesp.net/wiki/Tes3Mod:Catego ... ction_List
2. http://www.uesp.net/morrow/editor/mw_cscommands.shtml
3. http://wiki.theassimilationlab.com/mmw/ ... or_Dummies
4. msfd 9
5. http://mwmodders.com/scriptingnotes.html
6. https://www.tamriel-rebuilt.org/content ... ng-dummies

Lua was decided to be newscript.
This has been the most debated.
Better documentation in zini's design doc for needed features.
viewtopic.php?f=20&t=5256

1. sys::
2. script hooks

Scripting rules from Scripting_for_Dummies in vanilla

1. inconsistent use of commas can lead to compile errors.
2. "If the ID contains a space or begins with an underscore, you must use quotation marks"
3. leave a space around parantheses and operators. can cause problems otherwise.
4. "a x"-> works but "a x" -> not always like x ->, don't use spaces should work

Safegame corruption crashes in vanilla:

1. Loading savegame with outdated modinfo + secondly loading second save with recent info,
   seems to notice commas and letters in script, but not numbers

---------------------------------------------------------------------------
getbuttonpressed

Code: Select all

   
   1)  Gets the messagebox result starting from 0 for first button 
         and returns otherwise -1 when messagebox is not open, 
         https://gitlab.com/OpenMW/openmw/issues/917
       

results:

1. Getbuttonpressed without linked messagebox is supposed to scan messagebox from any script, so any choise as its itself in script is overglowing by design.
2. This causes blocking the referred free floating? result on other local scripts.
3. Getting getbuttonpressed from messagebox needs mechanism to wait one frame for the info to be processed and useful.
4. ie. OnActivate can't be 1 on the same frame as GetButtonPressed is not -1 (from capo)
5. Menumode check can be used prevent script execution while in menus ie. activated container, etc.

For above mentioned reasons and one eluded, structure needs to be exactly same as in http://wiki.theassimilationlab.com/mmw/ ... e_executed

Namely with onactivate:

Code: Select all

short button
short tag

if ( onactivate == 1 )
	if tag == 0
    	messagebox "resharge" "ok then dear" "almsivi allmighty"
		set tag to 1
	endif
endif
	
if tag == 1
	set button to getbuttonpressed
	if ( button == 0 )
		player->additem "repair_journeyman_01" 1
		set tag to 0
	endif
	if ( button == 1 )
		player->additem "p_restore_fatigue_q" 1
		set tag to 0
	endif
endif

Otherwise multiple messageboxes in same cell doesn't work as intented
and it's mess https://gitlab.com/OpenMW/openmw/issues/2676
---------------------------------------------------------------------------
messagebox

Spoiler: Show

In msfd 9 there's a section for messagebox. Variables can be shown with % mark.
Already script defined can be shown with %.ab where

a= number of digits displayed, works for only float, others are ignored
b= ... value type.

1. original help D for short, game works with g wiki: "-32,768 to 32,767"
2. original f for float, works in game. wiki: "3.4e+38 to 3.4e-38" "7 digit precision"
3. in game G for long wiki: "-2,147,483,648 to 2,147,483,647"
4. original S for string, not implemented

5) using commas in numbers or D, S, a, t, other letters fails to compile the script ingame
6) is there cases where type is important?
viewtopic.php?f=2&t=2826&start=10

in vanilla switching G/g have no effect on result and the value is read from given variables. Getsecondspassed is given with accuracy upto 15 decimals. rest is zeros.

.x is for decimals:

1. g/g, G/g, G/G | a,b,c "a.0d and b.20 with -2e+009"
2. g/g | c,b,a "-2e+009 and b.20 with a.0"
3. f/f/f | a,b,c "a.6 and b.20 with c.7

Also in vanilla while xg doesn't effect decinals it shows the number of integers, showing vs e+002 etc mark.
Don't know how to test if the value is converted to float and does this matter in mods.

In openmw

1. g/f/G "a with b.3" bug.
2. g/f/g same
3. f/f/f | a,b,c "a.0 and b.3 with c.0" in time zeros are not shown + only tree decimals

tests:

Spoiler: Show

Code: Select all

begin messagebox

short a
float b
long c

set a to random 1000
set b to ( b + getsecondspassed )
set c to -2000000000

if ( onactivate==1 )
    messagebox " messagebox "%.6g and %.20f with %.7G", a, b, c, "ok"
endif

end

---------------------------------------------------------------------------
enablestatreviewmenu

theory

Code: Select all

    1) in vanilla read values directly from played game, buggy, popping up all the inventorywindows.
          	in openmw same, unbuggy https://github.com/OpenMW/openmw/pull/1257

Spoiler: Show

Code: Select all

begin enablestatreviewmenu

if ( onactivate == 1 )
      enablestatreviewmenu
endif

end

---------------------------------------------------------------------------
disable / delete

Code: Select all

    1) in vanilla disable removes the target from the world but set delete only partially works, calling functions working
        before cell reload
    2) openmw disable removes target from renders and collision and set delete is straightforward deleting.

---------------------------------------------------------------------------
centeroncell, coc

Code: Select all

1) in vanilla player damage seems to be calculated from end position while in openmw there is a bug causing the start
    position come into account https://gitlab.com/OpenMW/openmw/issues/2629 (fixed)

tests:

Spoiler: Show

Code: Select all

begin teleportdeath

float timer 
;this should cycle trought seyda neen and rethan manor still player is dead from bug
;requires that next line and script is run as every frame global 

set timer to ( timer + getsecondspassed )

if ( getpccell "rethan manor" == 1 )
    if ( timer > 10 )     
     player->position -11500 -67800 300000 0
     set timer to 0 
    endif
endif

if ( getpccell "seyda neen" == 1 )
    if ( timer > 10 )
      coc "rethan manor"
     set timer to 0
    endif
endif
       
end

---------------------------------------------------------------------------

Code: Select all

begin teleportdeath1

float timer 
;for vanilla test case soltheim is better used

set timer to ( timer + getsecondspassed )

if ( getpccell "rethan manor" == 1 )
    if ( timer > 10 )     
     player->positioncell 100 100 0 0 "solstheim" 
     set timer to 0 
    endif
endif

if ( getpccell "solstheim" == 1 )
    if ( timer > 10 )
      coc "rethan manor"
     set timer to 0
    endif
endif
       
end

---------------------------------------------------------------------------
position x y z zrot

Code: Select all

    1) consoling player -> position 0 0 32000 0 works in openmw 
       failsafes to 0 0 ground if underground.
       300 000 000 height is possible but results in mesh clipping due to world origin distance
       
       in vanilla, console takes only x,y,zrot values and defaults on ground 
       position -1000 -70000 (any value) 0         teleports as  intended near seyda neen but at the z height of 1000 
       
       test: defaulting to ground on actors, statics

test for variables: works

Spoiler: Show

Code: Select all

Begin sj_aplacement

float x
float y
float e

set e to (player->getpos z) + 10
set y to (player->getpos y) + 100
set x to (player->getpos x) + 100

"hannabi zabynatus"->position x y e 0

End sj_aplacement

---------------------------------------------------------------------------
positioncell



---------------------------------------------------------------------------
GetPCTraveling and GetPCInJail

both returns 0 in one frame after new cell is loaded
https://github.com/OpenMW/openmw/pull/1868

testing script by LennyPenny
https://upl.io/i/4ct8te.mp4

Spoiler: Show

Code: Select all

Begin aaa_cellchange_frame_test

short pew

float lastx
float lasty
float lastz

float nowx
float nowy
float nowz

if (getPCtraveling == 1)
	set lastx to (player->getpos x)
	set lasty to (player->getpos y)
	set lastz to (player->getpos z)
	set pew to 1
endif

if (pew == 1)
	if (getPCtraveling != 1)
		set nowx to ( player->getpos x )
		set nowy to ( player->getpos y )
		set nowz to ( player->getpos z )
		messagebox "pos now: %.2f %.2f %.2f" nowx nowy nowz
		messagebox "pos before: %.2f %.2f %.2f" lastx lasty lastz
		set pew to 0
	endif
endif

End aaa_cellchange_frame_test

---------------------------------------------------------------------------
startcombat, stopcombat

use cases

1. targeting file placed references
2. console placed references (doesn't work in vanilla)
3. script placed references
4. unigue references from base game
5. local script
6. global script
7. dialogue results
8. interaction with setfight

Spoiler: Show

simple local script

Code: Select all

Begin aaacombattestlocal

short done

if done=0
	startcombat aaanina
	set done to 1
endif

End aaacombattestlocal

global targeting

Code: Select all

scripted fight

Code: Select all

---------------------------------------------------------------------------
random

Code: Select all

   1) before bloodmoon patch unreliable on small numbers. in openmw c++ generators
   2) in vanilla seems to fire about 20 times a frame while in openmw once every frame
   3) should work with operators  if ( random 20 == 10 )  

test:

Spoiler: Show

Code: Select all

begin testrandom

short a
short n1
short n2
short n3
short n4

set a to random 3

if ( a == 0 )
    set n1 to ( n1 + 1 )
  elseif ( a == 1 )
    set n2 to ( n2 + 1 )
  elseif ( a == 2 )
    set n3 to ( n3 + 1 )
  elseif ( a == 3 )
    set n4 to ( n4 + 1 )
  endif
  endif
  endif
endif

if ( onactivate == 1 )
    messagebox "%.0g, %.0g, %.0g, %.0g" n1 n2 n3 n4 
endif

end

---------------------------------------------------------------------------
for scripts + testing mods
possibly cross referencing scripting systems in the future

Spoiler: Show

Code: Select all

Begin aaaactivationtimes

short n

if ( onactivate == 1 )
    messagebox "%g" n
	set n to n+1
endif

End aaaactivationtimes

related to https://gitlab.com/OpenMW/openmw/issues/999

ungategorized scripts:

Spoiler: Show

Code: Select all

Begin aaagetdistancemes

float g

set g to getdistance player

if ( getdistance player < 1000 )
	messagebox "%g" g
endif

End aaagetdistancemes

msfd 9 on the table
test scripts, structures are more than welcome : )
also advice on formatting.

Spoiler: Show

changelog:
added lines
corrected syntax
getbuttonpressed and random scripts
getbuttonpressed bugtracking
%.xg behavior in vanilla + random gen rates
disable / delete

redits:
nakashi for syntax advice.
asmo for general bugtesting initiative.

in openmw for patience.
bugtesters and modders on openmw and vanilla side for ideas.
msfd 9 and who have contributed to manuals over the years.
who all are clearly too numerous to list here.
controversial but thanks for bethesda for buggy engine what have driven players mad enought to write a new engine and stay on modding
and for the great game.

Documentation also partially in here https://github.com/sjek/scripts-workspace

[sjek]

Spoiler: Show

can the script testing be started in osg port?
ie. are the handles already coded in or is it better to wait still 37.0, so that the rendering is more bugtracked. anyway still bugs has eased.
like when games are sometimes referred to be written on ps4

many bugs / script commands are tied in a way or another to rendering. some are also kinda inbetween, basically working in the background but otherwise not showing in game. unsure from the "which is which"

one way would be making scripts now and testing them in osg later ofc.
anyway writing some in the meantime

edit: placing here some of written scripts, these may be complicated or simple, most using probably feature(s) not possibly in vanilla.
copyright is CC0 ie. free to use, mod, share or whatever pops into mind


Spinning quest hindering player control relative to eldafire's movement, including fargoth as a sidekick:
---------------------------------------------------------------------------------------------
This can be extended with dialogue kinda simply by targeting script variables.
Eldafire is basically moving across ridge from side to side, which make fargoth disappear in one direction and affects direction of the player's rotation on both. xP

There's three scripts from which
1. travelingtrigger makes eldafire walk the gridge back and forth
2. handlewitch deals with variable rotating speed of player when activator in question has been activated
3. spinningdist rotates fargoth in speed relative to distance to player after treshold

Spoiler: Show

Code: Select all

Begin travelingtrigger
;writer: sjek
;licence:CC0

float timer
short walkdirection
short traveltimer
short setstage
short rotspe

;features used: variable on rotate and on player
;as a global at least. rotating also affects player
;anywhere in the game world, 
;if there's not separate checks for certain areas.

;with spin angles 120 and -120 player needs to look
;only lightly left or right from 0
;leaving 60 degrees from 360, depending 
;from eldafire's direction, as rotation free angle

if setstageonce==0
	set traveltimer to 6

 	eldafire->aitravel -11380 -68559 236
		;ensure that eldafire's aiwander don't override aitravel
		;letting script to start

	set setstageonce to 1
endif

set timer to timer+getsecondspassed

if walkdirection==0
	eldafire->aitravel -11380 -68559 236
		;eldafire travels to other end of the fridge

	if (player->getangle z < 120)
                ;sets the angle limit after which player starts to spin
     
		player->rotate z rotspe
			;rotation and it’s speed called every frame
 
	elseif (timer>traveltimer)
		;time after which eldafire can turn around
		;and other direction can be set

		if eldafire->getaipackagedone==1
			;ensures that ridge is crossed
			
			player->modspeed 50
			fargoth->disable
				;effects while eldafire 
				;is traveling to other direction
				;which are one time applied
			
			set timer to 0  
				;starts time over for next interval
			set walkdirection to 1  
				;jumps to next if block (other direction)
		endif
	endif
endif

;repeating above one to other direction with reverse effects
if walkdirection==1
	eldafire->aitravel -11390 -69994 241
	if (player->getangle z > -120)
		player->rotate z -rotspe
	elseif (timer>traveltimer)
		if eldafire->getaipackagedone==1
			player->modspeed -50
			fargoth->enable 
			set timer to 0
			set walkdirection to 0
		endif
	endif
endif

End travelingtrigger

Code: Select all

Begin handlewitch
;writer: sjek
;licence:CC0

short turn

;feature used: change the other's scripts variable refetably bug free


if onactivate==1
	;activation from activator in game

	set turn to 1
endif

if turn==1       
	;in this case rotate on every frame, while turn==1 being true

	rotate z 40
	if ( getangle z <10 )
		;start the speed change checks

		set travelingtrigger.rotspe to 10
			;change the speed value for player's rotation
         ;in another script based on angles
			;incremented mwscript style 
	elseif ( getangle z <20 )
		set travelingtrigger.rotspe to 20
	elseif ( getangle z <30 )
		set travelingtrigger.rotspe to 30
	elseif ( getangle z <40 )
 		set travelingtrigger.rotspe to 40
	elseif ( getangle z <50 )
		set travelingtrigger.rotspe to 50
	elseif ( getangle z <60 )
		set travelingtrigger.rotspe to 60
	elseif ( getangle z <70 )
		set travelingtrigger.rotspe to 70
	elseif ( getangle z <80 )
		set travelingtrigger.rotspe to 80         
	elseif ( getangle z <280 )
		set travelingtrigger.rotspe to 90
	elseif ( getangle z <360 )
	 	set travelingtrigger.rotspe to 0
			;given the 80 degree difference(280 360)
                        ;back at speed 40, 
			;the player gets two seconds of non turning time
	else
		setangle z 0
            ;when going over 360, reset to 0 for script to work
            ;as engine turns over to infinity
            ;transition between angles seems to be seamless
	endif
endif

End handlewitch

Code: Select all

Begin spinningdist
;writer: sjek
;licence:CC0

float npcdist
short border

;feature used: variable calculation on rotate and applies it to actor

set npcdist to (fargoth->getdistance, player)
set border to 1000

if ( npcdist < border )
	;set the distance from where on fargoth starts to rotate

	fargoth->rotate z ((30*border) / npcdist)
endif

End spinningdist

Hrisskar in arrille tradehouse says things while in specific distance or sees you and scripted related effect with randomised outcome
----------------------------------------------------------------------------------------------
this works in openmw (say function in dialogue works, while not bugfree in vanilla) and for the health reduce, the else is triggered, if getlos player isn't 0 and rand > 99, bypassing both if clauses before else.

kills player kinda quickly with random < 50 and modhealth -10
(note: modhealth can't be seen unless in inventory as it's affects maxhealth)
diminishing hp while speaking need modhealth inside saydone

Spoiler: Show

Code: Select all

Begin arrillehriskar

float time
short rand
short saydone 
	;saydone returns 1 if targeted actor (script holder) isn't speaking

set rand to random 100
       ;set the stock from where to take the hp reducing change in this case
set time to (time + getsecondspassed)

if menumode==0
           ;if not in dialogue or menus
    if time > 5
                ;time in seconds before another say triggers

        if getdistance player < 600
                ;player must sneak behind stairs wall or behind arrille desk 
                ;in that distance, hrisskars standing in place
 
            if getlos player == 0
                ;seen by hriskar

                if saydone==1
                    say "Vo/n/m/bHlo_NM018.mp3" "alfred tells me things, friend... secret things"
                endif

            elseif rand < 99
                    ;change from set of random to say. 
                    ;probaply better to write distance 
                    ;and/or race, journal check.
				
                if saydone==1
                    say "Vo/n/m/bHlo_NM030.mp3" "aahhh... you arrived. these are trange times my friend"
                endif

            else
              player->modhealth -1
                ;things to do while hriskar isn't seeing you and rand > 99
                ;for showcasing and as effect player max health props 
                ;as not showing directly to player,  cast stormhand player  
                ;to damage health and for more visible effect
            endif
        endif
    endif
endif

if time > 10
	set time to 0
		;to repeat above shedule making repetition time 5 on and 5 off, etc
		;as time isn't changed inside above if clause.
endif

End arrillehriskar

Spinning object, caster, while turns angles (unique gold ganet)
-------------------------------------------------------------------------------
Ability to shoot the player with fireball once in a turn. shooting more fireballs than one may be possibly with high framerate, angles over 290 registering multiple times, but it turns on the same value so it's might need to be pretty high.

Uses openmw ability for activators casting targeted spells.
This could also be used to make part of dialogue or event triggered maze, as changing script variables from dialogue, ie other than script is intended to work in openmw bugfree.

Spoiler: Show

Code: Select all

Begin dangerousflower

short fire

;rotates and checks when turning over limits and changes fire variable,
;causing the direction to change.
if fire == 1
	rotate z 60
	if getangle z > 290
		set fire to 0
	endif
elseif fire == 0
	rotate z -60
	if getangle z < 10
		set fire to 1
	endif
endif

if getangle z > 290
	;fires the spell in question to palyer when the check passes,
	;in this case the upper limit in angles going over.

	cast "fireball" player
endif

End dangerousflower

Other one with more spinning in somewhat random directions.

Code: Select all

Begin aaarot

float n
float b
short c
float a

set n to (n+getsecondspassed)

set b to ( aaaa->getangle x - aaaa->getangle y )

if a=1
	aaaa->rotate x -16
endif

if a=0
	aaaa->rotate x ( 10 * n )
	aaaa->rotate y ( 5 * n )
	aaaa->rotate z ( 10 * n )
endif

if b >= 100
	set a to 1
	if c=0 
		aaaa->cast Fireball "player"
		set c to 1
	endif
elseif b<50
	set a to 0
	set c to 0
endif

End aaarot

-------------------------------------------------------------------------